script action three

Updated Youtube ID retrieval...

2011-10-06T22:32:00.001-07:00

// get the youtube ID from a link, look ma, no REGEX!
// to accomodate the new short URL format

function getVideoId(url){
if(url.indexOf('?') != -1 ) {
var query = decodeURI(url).split('?')[1];
var params = query.split('&');
for(var i=0,l = params.length;i if(params[i].indexOf('v=') === 0)
return params[i].replace('v=','');
} else if (url.indexOf('youtu.be') != -1) {
return decodeURI(url).split('youtu.be/')[1];
}
return null;
}
var urlOLD = "http://www.youtube.com/watch?v=UF8uR6Z6KLc&feature=feedlik";
var urlNEW = "http://youtu.be/UF8uR6Z6KLc";
trace(getVideoId(urlOLD));
trace(getVideoId(urlNEW));

Animating perspectiveProjection AS3 (CS5)

2011-08-01T06:45:00.000-07:00

I use TweenMax a lot, but sometimes you need to animate a complex object or 3D object.

In this case, it's the perspectiveProjection class of the native 3D features of flash player 10, in particular it's fieldOfView and focalLength properties.

Why bother with this at all? Well, although you probably can't do mesh, the native 3D features can be much faster than libraries like Away3D for simple 3D effects.

View demo. Download example.

And below is the code, just in case you want to jump right in... (sorry for the procedural code!)

import com.greensock.TweenMax;
import com.jibjub.quickZsort;

TweenMax.to(cube_test, 10, {rotationX:700, rotationZ:400, rotationY:500, repeat:-1, yoyo:true});

//new PerspectiveProjection
var pers:PerspectiveProjection = new PerspectiveProjection();
//set the field of view - doesn't really do much
pers.fieldOfView = 1;//Default: 55, Range: 1 - 180
//set the focal length
pers.focalLength = 1000;//Default: 663
//set the projection center to stage center for a straight view
pers.projectionCenter = new Point(stage.stageWidth * 0.5, stage.stageHeight * 0.5);

// tween the perspective projection
TweenMax.to(pers, 1, {fieldOfView:179, repeat:-1, yoyo:true});

// apply the perspective each frame (and also z-sort out clips)
addEventListener(Event.ENTER_FRAME, function(){
    quickZsort.sort(cube_test);
    //assign to target/DisplayObject
    cube_test.transform.perspectiveProjection = pers;
});

stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;

addEventListener(Event.RESIZE, onResize);
stage.addEventListener(Event.RESIZE, onResize);

function onResize(e:Event) {
    // keep our vanishing point centred
    pers.projectionCenter = new Point(stage.stageWidth * 0.5, stage.stageHeight * 0.5);
    // keep our cube centred
    cube_test.x = stage.stageWidth * 0.5;
    cube_test.y = stage.stageHeight * 0.5;
}

auto hide/show UIScrollBar after updating text AS3

2011-02-20T19:07:00.000-08:00

// after updating the text (can be text or htmlText)...

my_textfield.scrollV = 0; // reset the scroll to the top
my_scrollbar.update(); // make sure the scrollbar knows it's been changed
if (my_scrollbar.maxScrollV <= 1) {
my_scrollbar.visible = false;
} else {
my_scrollbar.visible = true;
}

Useful displayObject Utilities

2011-02-06T17:33:00.000-08:00

// remove any displayObject, irrespective of location (remove a parent from the child etc)
function kill(object:*):void {
if(object.parent != null){
var parent:DisplayObjectContainer = object.parent;
parent.removeChild(object);
}
}

// remove all contents of a target MovieClip
function burn(target:MovieClip):void {
while (target.numChildren) target.removeChildAt(0);
}

removeChild() from the child itself AS3

2010-08-14T01:56:00.000-07:00

function destroyMe(object:*):void {
        if(object.parent != null){
                var parent:DisplayObjectContainer = object.parent;
                parent.removeChild(object);
        }
}

AS3 subscript and superscript with CSS

2010-07-13T00:22:00.000-07:00

var style:StyleSheet = new StyleSheet();
style.parseCSS('sub{font-family:"GG Subscript";}sup{font-family:"GG Superscript";}');
myDynamicTextfield.styleSheet = style;

Outstanding Tutorial on Physics in AS3

2010-04-12T22:48:00.000-07:00

http://active.tutsplus.com/tutorials/effects/introduction-to-quickbox2d-part-1/

Validate a youtube link and extract the ID with regular expressions AS3

2009-05-13T04:44:00.000-07:00

// you can just copy paste, I don't feel like colouring all this code :)

// input a youtube link (or embed code)
var youtubeInput:String = "http://www.youtube.com/watch?v=LGq271wYzow&feature=related&fmt=18";
// our regular expression to extract the youtube ID
var youtubeIDRX:RegExp = /\?v=(.{11})|\/v\/(.{11})/;
var youtubeFeedURI:String = "http://gdata.youtube.com/feeds/api/videos/";

var youtubeLoader:URLLoader = new URLLoader();
youtubeLoader.addEventListener(Event.COMPLETE, parseYoutubeFeed);
youtubeLoader.addEventListener(IOErrorEvent.IO_ERROR, youtubeFeedERROR);
function parseYoutubeFeed(myEvent:Event):void {
var xml:String = myEvent.target.data;
//trace(xml);
if (xml.indexOf("noembed") != -1) {
// looks like embed is turned off, let them know to turn it on
trace("not a tube we can embed.");
} else {
// everything's cool
trace("cool bananas, let's hopscotch!");
}
}
function youtubeFeedERROR(e:Event = null):void {
// it might not be a tube if this doesn't load, but they might not have internet either...
trace("not a tube?");
}

if (youtubeIDRX.test(youtubeInput)) {
var RXresultArray:Array = youtubeIDRX.exec(youtubeInput);
if (!RXresultArray) {
// if there's nothing in the array, they probably didn't give us the right link
trace("not a tube.");
} else if (RXresultArray[1]) {
// if there's something here, it's probably a URL they gave us
trace(RXresultArray[1]);
youtubeLoader.load(new URLRequest(youtubeFeedURI + RXresultArray[1]));
} else if (RXresultArray[2]) {
// if there's something here, they pasted an embed tag, silly duffers...
youtubeLoader.load(new URLRequest(youtubeFeedURI + RXresultArray[2]));
trace(RXresultArray[2]);
} else {
// I have no idea how they could get here but anyway, we can't help them...
trace("not a tube?");
}
} else {
// I don't think it was a youtube link they gave us..
trace("not a tube?");
}

Security Risk: No Cookies in FileReference.upload();

2009-04-29T09:50:00.000-07:00

// SECURITY PROBLEMS, we need cookies in FileReference.upload();

cookies work fine when using URLRequest but not when using upload() ??!! In the mean time, I thought of something... Not perfect but at least stops the casual hacker (as is currently the vulnerability)

When we start the upload, we do two things. First, make a URLRequest to a php page that cross checks the session data, if it checks out, store their IP address in a database table

In the actual upload.php file, simply open the database, compare the IP address inbound to the one validated by the cookies. If these match, we have a pretty strong case for letting them write to the server. You could take it a little further and add store a timestamp or epoch, then compare that to an acceptable time window to complete an upload, but you might cut of some 56k modems...

2009-03-01T21:10:00.000-08:00

If you live in Victoria, tomorrow is supposed to be a very dangerous day, even in the city with combination of high wind and fire risk, they can't use the fire aircraft. You probably already received and SMS from Vic Police and it is no hoax. Make sure you monitor the
fires tonight and tomorrow and listen to local ABC Radio for emergency updates.
More here.

Preloading External Assets AS3

2009-03-01T16:28:00.000-08:00

Do you need to preload multiple assets before your movie starts? Like jpg's, mp3, fla or collada files? Here is a really neat pre-loader class in AS3: code.google.com/p/bulk-loader/

Blur Focus AS3

2009-02-04T23:28:00.001-08:00

blurFocus, hideFocus, just get rid of that damn focus:

this.stage.focus = null;

Clicking Through MovieClips to Underlying Objects AS3

2008-11-22T00:36:00.000-08:00

here we use the mouseEnabled property on the obstructing clip.

myMovieClip.mouseEnabled = false;

Resize swffit AS3

2008-11-06T21:03:00.000-08:00

Double check that the "swffit.fit" matches your javascript and also "my_flash". eg, in your HTML: swffit.fit("my_flash", 1024, 2000);

import flash.external.ExternalInterface;
function resizeSwffit(newWidth:Number, newHeight:Number):void {
ExternalInterface.call("swffit.fit","my_flash",newWidth,newHeight);
}

reverse set ComboBox as3

2008-11-06T18:57:00.000-08:00

You can use selectedIndex to change a comboBox, but the selectedIndex is usualy independent from the data or the label properties of the Object. Apparently there is no way of doing a reverse look up to select the item, you have to searh through and find it yourself (if you know a better way, let me know!).

function reverseSetComboBox(target:String, targetComboBox:ComboBox, targetDataProvider:Array):void {
        //loop over the items in the dataProvider
        for (var i:uint = 0; i<targetComboBox.length; i++) {
                //compare desired value to current item.data value
                if (target==targetDataProvider[i].label) {
                        //set the seletedIndex of the combo box
                        targetComboBox.selectedIndex = i;
                }
        }
}

Call an Event function indirectly in AS3 with dispatchEvent

2008-10-16T06:22:00.000-07:00

Event listeners are a great way to work but if you have an event function, you can't just call it directly in the script anymore (ala AS2), well you can try, but you will get an argument error. You can, however, dispatch a matching event to trigger listener and fires that function.

Perhaps you have a timer event that calls a function and you want to call without involving the timer or, a more common one, you have a script to do stuff when the stage is resized, but you want to execute that function when the movie first loads:

stage.addEventListener(Event.RESIZE, resizeHandler);
stage.dispatchEvent(new Event(Event.RESIZE));

using REAL http cookies in flash AS3

2008-09-04T22:29:00.001-07:00

Using real cookies just makes sense for some tasks and can also make your life easier as any urlRequest includes them, great news for your server side processing.

As you can imagine, google gets a little confused with so many different "cookies" and comes back with one of two things...

1. "flash cookies" (SharedObject)
2. Doufus saying "HEY WOW, I figured out how to use cookies! just put them in the swf URL / loaderInfo flashvars!"

firstly, "flash cookies" are useless if you are calling php or asp files because they are not passed with the http request and as for the second option, it is poor security not to mention a pain in the ass to include cookie values in a URL.

A third approach was to use ExternalInterface to call a javascript function on the page that returns the cookie value, again, this is poor security because the value can just as easily be modified and faked. but it is closer to our goal.

The solution we came up with was to keep all the javascript flash side and pull the cookie string apart.

// make a javascript call in flash to return cookies from the DOM
var cookieValue:* = ExternalInterface.call("function(){return document.cookie;}");

view a demo

remember, you will need to refresh the page for the flashvars method to work [you can't set and get a cookie at the same time]

download example files

recursive removeChild AS3 (unloadMovie)

2008-08-09T20:51:00.000-07:00

you may be tempted to use a for loop to recursively remove movieclips or sprites nested in another display object.
but this single line will take care of it for you:

while (mySprite.numChildren) mySprite.removeChildAt(0);

AS3 for loop

2008-08-03T17:44:00.000-07:00

var myArray:Array = new Array(1, 2, 3, 4, 5);

// loop through an array with uint
var i:uint;
for (i=0; i<myArray.length; i++) {
trace(myArray[i]);
}

HEX to RGB to greyscale conversion

2008-06-25T20:03:00.000-07:00

Converting a hex value to the equivalent grey scale is not as simple as averaging the values and dividing by 3 as the eye responds more to the green content than to red or blue.

There are different formulas in use, but a common one is 0.30*r + 0.59*g + 0.11*b

// split HEX into RGB components
var r = hex >> 16;
var g = hex >> 8 & 0xFF;
var b = hex & 0xFF;
// create a new grey value
var grey = 0.30*r + 0.59*g + 0.11*b;
// create a new HEX colour
var k = grey.toString(16) + grey.toString(16) + grey.toString(16);

AS3 setInterval

2008-05-15T00:04:00.000-07:00

// new Timer([interval], [repeat]);
var myTimer:Timer = new Timer(500, 10);

myTimer.addEventListener(TimerEvent.TIMER, myFunction);

function myFunction(event:TimerEvent):void {
trace(myTimer.currentCount);
}

// start the timer
myTimer.start();

AS3 basic XML use

2008-05-05T23:09:00.000-07:00

// we use URLLoader instead of XML.load();
var loader:URLLoader = new URLLoader();

loader.addEventListener(Event.COMPLETE, loadXML);
loader.load(new URLRequest("example.xml"));

function loadXML(myEvent:Event):void {
        var xml:XML = new XML(myEvent.target.data);
                // you can now traverse the xml object using the actual tag names
                trace(xml.tagname.anothertagname.text());

                // you can also target all tags of a certain name
                // with the .. "descendent accessor"
                trace(xml..anothertagname.length());

                // and we use the @ accessor for attributes
                trace(xml.tagname.anothertagname.@myattribute);
                //
}

// here is some xml for your example.xml file

/*

<?xml version="1.0" encoding="UTF-8" ?>
<xml>
<tagname>
<anothertagname myattribute="my attribute goes here">my text goes here</anothertagname>
</tagname>
</xml>

*/

AS3 stage height and width (+ Hello)

2008-04-29T00:50:00.001-07:00

A pretty common one and In AS2 you would access this property like this:

trace(Stage._height);
trace(Stage._width);

So in AS3, you might at first try something like this:

trace(stage.width);
trace(stage.height);

Only to find it now returns the bounds of any objects on the stage.
We now access the stage width and height in AS3 like this:

trace(stage.stageWidth);
trace(stage.stageHeight);

Have a nice day.

This is a new blog for people like me, who are migrating to from actionscript 2 (AS2) to actionscript 3 (AS3) out of necessity. I will be speaking mainly to [myself] people like me who are already professionals who can deliver AS2 projects swiftly and are now in need of maintaining client expectations so this blog will be light on the basic descriptions of how stuff works and feature a lot of code to copy and paste straight into a new document to get your AS3 projects over the line and on time.

I will colour the code, but I will leave the AS2 code (depreciated) in a nice comment shade of grey.

A little about me; I am a professional flash and web-application developer, I am also currently a sessional lecturer at Swinburne University teaching flash. OK.